Командная строка

Ctrl + C - отмена действия в командной строке.
cls - очистить окно командной строки.

---

ipconfig или ipconfig /all - быстро найти IP-адрес.
ping tre.kz или ping 8.8.8.8 -t - проверка сети и подключения.
pathping tre.kz или pathping 195.210.46.91 - трассировка маршрута.
tracert batas.kz или tracert 195.210.46.91 - проследить маршрут отправленного пакета.
nslookup batas.kz - работа с сервером DNS из командной строки.
netstat -an - список сетевых подключений и порты.
getmac /v /fo list - отображение физического адреса сетевого адаптера (MAC-адреса).
arp -a - отобразить таблицу соответствия IP и MAC адресов для данного компьютера.
arp -a 192.168.0.101 - Узнать по IP, MAC-адресов
net view - Посмотреть список доступных в сетей.

---

md C:\test - создаём папку
cd C:\test - открываем папку
copy nul empty.txt - создаем пустой файл
copy con empty2.txt - создаем файл с содержимым
more empty2.txt - посмотреть содержимое файла
edit empty2.txt - изменить содержимое файла (до Windows 7)
ren empty.txt empty3.txt - переименовать файл или папку
copy /Y file1.txt file2.txt - копировать файл или папку
xcopy /E /C /I /Y /H C:\test D:\test2 - скопировать все файлы и подкаталоги /S с перезаписью существующих без запроса /Y , включая скрытые и системные. /H с перезаписью файлов с атрибутом "Только чтение" /R и игнорированием ошибок /C
dir или dir C:\test - выводим список файлов папки
del /f /q empty.txt - удаление файла с атрибутом только для чтения и без запроса на подтверждение
rd /s /q C:\test - удаление дерева папок без запроса на подтверждение
start C:\Program Files или start https://batas.kz/ - открыть папку или ссылку

---

defrag C: /U /V – дефрагментация жесткого диска.
chkdsk C: /F /R /X – проверка и исправление ошибок жесткого диска.
sfc /scannow - проверка целостности системных файлов.
bootrec /FixMBR /FixBoot /RebuildBCD – полное восстановление загрузочных записей.
mdsched – диагностика оперативной памяти.

---

tasklist - список запущенных процессов
taskkill /F /IM notepad.exe - завершить процесс
wmic product get name,version,vendor - посмотреть список установленных программ
wmic product where name="Имя программы" call uninstall /nointeractive - удалить программу тихо

---

hostname - узнать имя компьютера
time - узнать или изменить время.
date - узнать или изменить дату.
shutdown /s /t 0 - выключение компьютера.
shutdown /r /t 0 - перезагрузка компьютера.
shutdown /l - выйти из системы.
rundll32 powrprof.dll,SetSuspendState 0,1,0 - сон (гибернация).
Rundll32.exe user32.dll,LockWorkStation - Блокировка экрана (Win+L).
shutdown /s /t 60 /f /l /m \191.162.1.53 – используется для перезагрузки, отключения и выхода из сеанса определенного пользователя локальной машины или удаленного ПК.

---

dir c:\windows\system32\*.msc - отобразить список файлов с расширением msc из каталога.
format /q /fs:NTFS f: /v:Батыр – форматировать флешку.
convert f: /fs:NTFS – используется для преобразования существующего тома (диска) файловой системы FAT/FAT32 в NTFS без потери данных.
systeminfo > C:\systeminfo.txt – вывод информации о системе на локальном компьютере в текстовый файл C:\systeminfo.txt.

---

msg "%username%" "Сообщение для отображения..." – отправка сообщений пользователю
msg * "Сообщение для отображения..." – отправка сообщений пользователю
mshta "javascript:alert('Сообщение для отображения...');close()" – отправка сообщений

---

Netsh - настройка сети:
netsh interface show interface
netsh interface ipv4 add address "Беспроводная сеть" 192.168.1.56 255.255.255.0 192.168.0.1
netsh interface ip set address "Беспроводная сеть" dhcp
netsh interface ip add dns name="Беспроводная сеть" addr=8.8.8.8 index=1
netsh interface ip add dns name="Беспроводная сеть" addr=8.8.4.4 index=2
netsh interface ip set dns name="Беспроводная сеть" source=dhcp

---

Раздать Wi-Fi
netsh wlan show settings – выводит информацию о сети и отображает ее состояние.
netsh wlan show hostednetwork setting=security – выводит параметры безопасности сети.
netsh wlan set hostednetwork disallow – отключает режим размещенной сети.
netsh wlan set hostednetwork allow – включает режим размещенной сети.
netsh wlan set hostednetwork mode=allow ssid="www.batas.kz" key="12345678" keyUsage=persistent – устанавливает настройки Wi-Fi сети.
netsh wlan start hostednetwork – запускает раздачу Wi-Fi.
netsh wlan stop hostednetwork – останавливает раздачу Wi-Fi.

---

wget -m ftp://user:password@192.168.0.12:21 - Скачиваем сайты целиком
wget -r -k -l 7 -p -E -nc https://mysite.kz/ - Скачиваем сайты целиком
curl https://curl.se/ca/cacert.pem --output cacert.pem - Скачать файл

---

Цвет фона и шрифта
0 - черный
1 - синий
2 - зеленый
3 - Аква
4 - красный
5 - фиолетовый
6 - желтый
7 - Белый
8 - Серый
9 - Голубой
A - светло-зеленый
B - Светлый Аква
C - светло-красный
D - светло-фиолетовый
E - светло-желтый
F - Ярко-белый

---

Переменные среды
%APPDATA% - Возвращает используемое по умолчанию размещение данных приложений. В Windows XP это C:\Documents and Settings\%UserName%\Application Data. В Windows 7 - C:\Users\%UserName%\AppData\Roaming.
%PROCESSOR_ARCHITECTURE% - Архитектура процессора. Возможные варианты: x86, IA64, AMD64.
%OS% - ОС
%USERNAME% - Имя текущего пользователя.
%CD% - Указывает путь к текущему каталогу. Идентична команде CD без аргументов.
%USERPROFILE% - Путь к профилю текущего пользователя.
%WINDIR% - Каталог, в котором установлена Windows.
%LOGONSERVER% - Имя контроллера домена, использовавшегося для авторизации текущего пользователя.
%HOMEPATH% - Возвращает полный путь к основному каталогу пользователя. Задаётся на основании расположения основного каталога. Основной каталог пользователя указывается в оснастке «Локальные пользователи и группы».
%DATE% - Возвращает текущую дату. Использует тот же формат, что и команда date /t. Создаётся командой Cmd.exe.
%TIME% - Возвращает текущее время. Использует тот же формат, что и команда time /t. Создаётся командой Cmd.exe.
%COMPUTERNAME% - Имя компьютера.
%TEMP% и %TMP% - Возвращает временные каталоги, по умолчанию используемые приложениями, которые доступны пользователям, выполнившим вход в систему. Некоторые приложения требуют переменную TEMP, другие — переменную TMP. Потенциально TEMP и TMP могут указывать на разные каталоги, но обычно совпадают.
%PROGRAMFILES% - Путь к каталогу Program Files.
%PROGRAMFILES(x86)% - Путь к каталогу Program Files (x86) в 64-разрядных системах для приложений архитектуры x86.
%PATH% - Указывает путь поиска исполняемых файлов.

---

%~dp0 - путь к текущему каталогу
%~nx0 - получить имя файла с расширения (myfile.exe)
%~n0 - получить имя файла без расширения (myfile)
%~x0 - получить имя файла без расширения (.exe)
%cd% - путь к текущему каталогу
whoami - выводит имя пользователя

---

Пример example.bat или example.cmd файла (сохранить файл в кодировке OEM 866)

@echo off

rem C:\Windows
echo %WINDIR%

rem C:\Windows
echo %SYSTEMROOT%

rem C:\Users\user
echo %USERPROFILE%

rem C:\ProgramData
echo %ALLUSERSPROFILE%
echo %ProgramData%

rem C:\Users\user\AppData\Local\Temp
echo %TEMP%

rem C:\Users\user\AppData\Local
echo %LOCALAPPDATA%

rem C:\Users\user\AppData\Roaming
echo %APPDATA%

rem C:\Program Files
echo %PROGRAMFILES%

rem C:\Program Files (x86)
echo %PROGRAMFILES(x86)%

pause

---

Пример example.bat или example.cmd файла (сохранить файл в кодировке OEM 866)

@echo off

:: Заголовок
title Заголовок окна

:: Цвет фона и шрифта
color A0

rem Это комментарий

:: Это тоже комментарий

echo Тут ваш код...

pause

---

Чтобы изменить кодировку (сохранить файл в кодировке windows 1251)

@echo off

chcp 1251 rem Windows-1251
::chcp 65001 rem UTF-8
::chcp 866 rem OEM 866 (DOS)

echo Тут ваш код...

pause

---

Windows в качестве сервера

:: Отключение автоматического восстановления
bcdedit /set {current} recoveryenabled no

:: Отключить гибернацию
powercfg -h off

:: Автоматический вход в Windows
REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /f /v DefaultPassword /t REG_SZ /d 123456
REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /f /v AutoAdminLogon /t REG_SZ /d 1
REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /f /v DefaultUserName /t REG_SZ /d user

:: Отключаем службы
net stop idsvc & sc config idsvc start= disabled rem Windows CardSpace
net stop SDRSVC & sc config SDRSVC start= disabled rem Архивация Windows
net stop seclogon & sc config seclogon start= disabled rem Вторичный вход в систему
net stop ProtectedStorage & sc config ProtectedStorage start= disabled rem Защищенное хранилище
net stop SCPolicySvc & sc config SCPolicySvc start= disabled rem Политика удаления смарт-карт
net stop TabletInputService & sc config TabletInputService start= disabled rem Служба ввода планшетного ПК
net stop bthserv & sc config bthserv start= disabled rem Служба поддержки Bluetooth
net stop ehSched & sc config ehSched start= disabled rem Служба планировщика Windows Media Center
net stop BDESVC & sc config BDESVC start= disabled rem Служба шифрования дисков BitLocker
net stop SCardSvr & sc config SCardSvr start= disabled rem Смарт-карта
net stop TapiSrv & sc config TapiSrv start= disabled rem Телефония
net stop RemoteRegistry & sc config RemoteRegistry start= disabled rem Удаленный реестр
net stop Fax & sc config Fax start= disabled rem Факс
net stop wuauserv & sc config wuauserv start= disabled rem Центр обновления Windows

powercfg /change monitor-timeout-ac 0 rem Не отключать дисплей
powercfg /change standby-timeout-ac 0 rem Отключить спящий режим
powercfg /change disk-timeout-ac 9999 rem Не отключать жесткий диск

:: Не удается включить сетевое обнаружение
net start Dnscache & sc config Dnscache start= auto rem DNS-клиент
net start FDResPub & sc config FDResPub start= auto rem Публикация ресурсов обнаружения функции
net start upnphost & sc config upnphost start= auto rem Узел универсальных PNP-устройств
net start SSDPSRV & sc config SSDPSRV start= auto rem Обнаружение SSDP

:: Отключить брандмауэр
netsh advfirewall set allprofiles state off

:: Автозапуск VirtualBox
"%PROGRAMFILES%\Oracle\VirtualBox\VBoxManage.exe" startvm "AdGuard_Home" --type headless
"%PROGRAMFILES%\Oracle\VirtualBox\VBoxManage.exe" startvm "Ubuntu_Server" --type headless
"%PROGRAMFILES%\Oracle\VirtualBox\VBoxManage.exe" startvm "Windows_Server" --type headless

:: Автозапуск VMware Workstation
"%PROGRAMFILES(x86)%\VMware\VMware Workstation\vmrun.exe" start "%USERPROFILE%\Documents\Virtual Machines\Ubuntu\Ubuntu.vmx" nogui

---

Полное стирание (перезапись) HDD: CCleaner, Eraser, аппаратное уничтожение

format D: /fs:NTFS /p:7

---

Сменить IP-адрес и DNS

@echo off

:: Показать имя интерфейса: name="Ethernet"
netsh interface ipv4 show interfaces

:: Добавить(изменить) IP-адрес
netsh interface ip set address name="Ethernet" static 192.168.0.122 255.255.255.0 192.168.0.1
rem netsh interface ip set address name="Ethernet" source=static addr=192.168.0.122 mask=255.255.255.0 gateway=192.168.0.1

:: Добавить(изменить) DNS
netsh interface ip delete dns name="Ethernet" ALL
netsh interface ip add dns name="Ethernet" 8.8.8.8
netsh interface ip add dns name="Ethernet" 8.8.4.4 2
rem netsh interface ip delete dns name="Ethernet" addr=ALL
rem netsh interface ip add dns name="Ethernet" addr=8.8.8.8
rem netsh interface ip add dns name="Ethernet" addr=8.8.4.4 index=2

:: Удалить(очистить) IP-адрес
netsh interface ip set address "Ethernet" dhcp
rem netsh interface ip set address "Ethernet" source=dhcp

:: Удалить(очистить) DNS
netsh interface ip delete dns name="Ethernet" ALL
rem netsh interface ip delete dns name="Ethernet" addr=ALL

---

Удалить временные папки и файлы

@echo off

del /F /S /Q /A "C:\Windows\Temp\*"
del /F /S /Q /A "C:\Windows\Prefetch\*"
del /F /S /Q /A "%temp%\*"
del /F /S /Q /A "C:\Windows\SoftwareDistribution\Download\*.*"
echo Y | rd /s c:\$Recycle.Bin rem Очистить корзину

---

Сброс сетевых настроек

@echo off

:: Сброс WinSock
netsh winsock reset

:: Сбросить стек TCP/IP
netsh int ip reset

:: Освободить IP-адрес
ipconfig /release

:: Обновить IP-адрес
ipconfig /renew

:: Очистить-сбросить кэш DNS
ipconfig /flushdns

---

Тихая установка программ (автоматизация)

@echo off

:: Google Chrome: https://www.google.com/chrome/?standalone=1
"%~dp0ChromeStandaloneSetup64.exe" /silent /install

:: Mozilla Firefox: https://www.mozilla.org/ru/firefox/all/
"%~dp0Firefox Setup x64.exe" /S

:: VLC: https://www.videolan.org/vlc/
"%~dp0vlc-win64.exe" /S

:: K-Lite Codec Pack: https://codecguide.com/download_kl.htm
"%~dp0K-Lite_Codec_Pack_Full.exe" /verysilent

:: Paint.NET: https://github.com/paintdotnet/release/releases/
"%~dp0paint.net.install.x64.exe" /auto

:: 7-zip: https://www.7-zip.org/
"%~dp07z-x64.exe" /S

:: qBittorrent: https://www.qbittorrent.org/download.php
"%~dp0qbittorrent_x64_setup.exe" /S

:: Wise Disk Cleaner: https://www.wisecleaner.com/wise-disk-cleaner.html
"%~dp0WDCFree.exe" /VERYSILENT /NORESTART

:: CCleaner: https://www.ccleaner.com/ru-ru/ccleaner/builds (окращенная версия)
"%~dp0ccsetup_slim.exe" /S

:: ONLYOFFICE: https://www.onlyoffice.com/ru/download-desktop.aspx?from=desktop
"%~dp0DesktopEditors_x64.exe" /VERYSILENT /NORESTART

:: LibreOffice: https://www.libreoffice.org/download/download/
msiexec.exe /i "%~dp0LibreOffice_Win_x64.msi" RebootYesNo=No /qn

:: Notepad++: https://notepad-plus-plus.org/downloads/
"%~dp0npp.Installer.x64.exe" /S

:: Geek Uninstaller: https://geekuninstaller.com/download
copy "%~dp0geek.exe" "%userprofile%\Desktop\Geek Uninstaller.exe"

:: AnyDesk: https://anydesk.com/ru/downloads
copy "%~dp0AnyDesk.exe" "%userprofile%\Desktop"

---

Путь к текущей папке

@echo off

:: "%~dp0file.exe"
echo %~dp0

:: "%cd%\file.exe"
echo %cd%

pause

---

Очистить очередь печати

@echo off

net stop spooler
del /f /q /s %systemroot%\System32\spool\PRINTERS\*.shd
del /f /q /s %systemroot%\System32\spool\PRINTERS\*.spl
net start spooler

---

Отключаем ненужные службы

@echo off

net stop idsvc & sc config idsvc start= disabled rem Windows CardSpace
net stop WSearch & sc config WSearch start= disabled rem Windows Search
net stop CscService & sc config CscService start= disabled rem Автономные файлы
net stop SensrSvc & sc config SensrSvc start= disabled rem Адаптивная регулировка яркости
net stop SDRSVC & sc config SDRSVC start= disabled rem Архивация Windows
net stop MpsSvc & sc config MpsSvc start= disabled rem Брандмауэр Windows
net stop seclogon & sc config seclogon start= disabled rem Вторичный вход в систему
net stop defragsvc & sc config defragsvc start= disabled rem Дефрагментация диска
net stop pla & sc config pla start= disabled rem Журналы и оповещения производительности
net stop WinDefend & sc config WinDefend start= disabled rem Защитник Windows
net stop ProtectedStorage & sc config ProtectedStorage start= disabled rem Защищенное хранилище
net stop SCPolicySvc & sc config SCPolicySvc start= disabled rem Политика удаления смарт-карт
net stop swprv & sc config swprv start= disabled rem Программный поставщик теневого копирования (Microsoft)
net stop Wecsvc & sc config Wecsvc start= disabled rem Сборщик событий Windows
net stop TabletInputService & sc config TabletInputService start= disabled rem Служба ввода планшетного ПК
net stop bthserv & sc config bthserv start= disabled rem Служба поддержки Bluetooth
net stop ehSched & sc config ehSched start= disabled rem Служба планировщика Windows Media Center
net stop BDESVC & sc config BDESVC start= disabled rem Служба шифрования дисков BitLocker
net stop SCardSvr & sc config SCardSvr start= disabled rem Смарт-карта
net stop TapiSrv & sc config TapiSrv start= disabled rem Телефония
net stop VSS & sc config VSS start= disabled rem Теневое копирование тома
net stop RemoteRegistry & sc config RemoteRegistry start= disabled rem Удаленный реестр
net stop WdiSystemHost & sc config WdiSystemHost start= disabled rem Узел системы диагностики
net stop WdiServiceHost & sc config WdiServiceHost start= disabled rem Узел службы диагностики
net stop Fax & sc config Fax start= disabled rem Факс
net stop PerfHost & sc config PerfHost start= disabled rem Хост библиотеки счетчика производительности
net stop wscsvc & sc config wscsvc start= disabled rem Центр обеспечения безопасности
net stop wuauserv & sc config wuauserv start= disabled rem Центр обновления Windows

---

Резервное копирование 1С базу и не только
Создаём папку Backup в любом месте, внутри папки создаем файл Start.bat. Добавить файл в планировщик задач (каждые сутки): Панель управления -> Администрирование -> Планировщик заданий

@echo off

rem Укажите путь к папке для архивации
set folder="C:\1c_base"

set day=%DATE:~0,2%
set month=%DATE:~3,2%
set year=%DATE:~6,4%

rem Вариант 1) ничего не требуется
xcopy /E /C /I /Y /H %folder% "%CD%\backup_%day%_%month%_%year%"

rem Вариант 2) должен быть установлен "7-Zip", если у вас "x86|32bit": %ProgramFiles(x86)%
rem "%ProgramFiles%\7-Zip\7z.exe" a -r0 -mx5 "%CD%\backup_%day%_%month%_%year%.zip" %folder%

rem Вариант 3) должен быть установлен "WinRAR", если у вас "x86|32bit": %ProgramFiles(x86)%
rem "%ProgramFiles%\WinRAR\Rar.exe" a -r -m5 "%CD%\backup_%day%_%month%_%year%.zip" %folder%

---

Внутренний и внешний IP адрес

@echo off

rem Внутренний IP адрес
for /f "delims=[] tokens=2" %%a in ('ping -4 -n 1 %ComputerName% ^| findstr [') do set ip_private=%%a

rem Внешний IP адрес
for /f %%a in ('powershell Invoke-RestMethod api.ipify.org') do set ip_public=%%a

echo Private IP: %ip_private%
echo Public IP: %ip_public%

pause

---

Узнать архитектуру Windows

@echo off

if /i "%PROCESSOR_ARCHITECTURE%" EQU "x86" (set arch=x86) else (set arch=x64)

echo Architecture: %arch%

pause

---

Сканирование IP

@ECHO Off

:: Кодировка OEM 866

ECHO Запуск сканирования IP...
FOR /L %%i IN (1,1,255) DO (
	ping -n 1 -w 25 192.168.0.%%i | FIND "TTL=" >NUL
	IF NOT ERRORLEVEL 1 (
		ECHO Пинг IP: 192.168.0.%%i - в сети
		ECHO 192.168.0.%%i>ips.txt
	) ELSE (
		ECHO Пинг IP: 192.168.0.%%i
	)
)
ECHO Сканирование IP завершено
ECHO Проверьте файл ips.txt чтобы увидеть результаты

---

Автоматизация Dr.Web CureIt! (drweb.exe)

@echo off

rem Скачать: https://free.drweb.ru/download+cureit+free/
rem Документация: https://download.geo.drweb.com/pub/drweb/cureit/doc/drweb-cureit-free-ru.pdf

md tmp

"%CD%\drweb.exe" /AA /FULL /NOREBOOT /OK /RP:"%CD%\tmp\report_drweb" /QUIT /SST /TB /TM /TR /AAD:D /AAR:D /ACN:D /ADL:D /AHT:D /AIC:D /AIN:D /AJK:D /ARW:D /ASU:D

---

Автоматизация Kaspersky Virus Removal Tool

@echo off

rem Скачать: https://www.kaspersky.ru/downloads/thank-you/free-virus-removal-tool
rem Документация: https://support.kaspersky.ru/8537
rem Командная строка: KVRT -h

md tmp

"%CD%\KVRT.exe" -d "%CD%\tmp" -accepteula -trace -tracelevel DBG -processlevel 2 -dontencrypt -details -noads -fixednames -silent -adinsilent -allvolumes

---

Установить корневые сертификаты NCALayer

@echo off

:: Auto install certificates NCALayer
:: Author: https://tre.kz

set dir=certificates
if not exist %dir% (md %dir%)

:: 1. Download certificate
curl --url https://pki.gov.kz/cert/root_rsa.crt --output %dir%/root_rsa.crt
curl --url https://pki.gov.kz/cert/root_gost.crt --output %dir%/root_gost.crt
curl --url https://pki.gov.kz/cert/root_rsa_2020.cer --output %dir%/root_rsa_2020.cer
curl --url https://pki.gov.kz/cert/root_gost_2022.cer --output %dir%/root_gost_2022.cer
curl --url https://pki.gov.kz/cert/nca_rsa.cer --output %dir%/nca_rsa.cer
curl --url https://pki.gov.kz/cert/nca_gost.cer --output %dir%/nca_gost.cer
curl --url https://pki.gov.kz/cert/nca_rsa_2022.cer --output %dir%/nca_rsa_2022.cer
curl --url https://pki.gov.kz/cert/nca_gost_2022.cer --output %dir%/nca_gost_2022.cer

:: 2. Install certificate
for %%a in (%dir%/*) do (
	certutil -addstore -f -enterprise -user root %dir%/%%a
)

:: 3. Delete folder
rd /s /q %dir%

---

Пример меню в bat-файле

@ECHO off
CLS
title Пример меню

:start
ECHO Меню
ECHO ------------
ECHO 1) Раздел 1
ECHO 2) Раздел 2
ECHO 3) Раздел 3
ECHO ------------

set choice=
set /p choice=Ваш выбор: 

if '%choice%'=='1' goto section_1
if '%choice%'=='2' goto section_2
if '%choice%'=='3' goto section_3

ECHO.
ECHO Ошибка! Неправильный выбор.
ECHO.
goto start

:section_1
ECHO.
ECHO Команда выполнена 1
ECHO.
goto end

:section_2
ECHO.
ECHO Команда выполнена 2
ECHO.
goto end

:section_3
ECHO.
ECHO Команда выполнена 3
ECHO.
goto end

:end
pause

---

Создать резервную копию драйверов Windows

@echo off

set folder=backup_drivers

cd "%~dp0"

mkdir %folder%

rem pnputil.exe /export-driver * %folder%
dism /online /export-driver /destination:%folder%

exit

---

RTSP Player, FFmpeg, VLC

@echo off

:: Example: rtsp://login:password@ip:port/live

rem ffplay.exe -window_title "IP Camera" -x 1280 -y 720 -rtsp_transport tcp "rtsp://104.194.11.25:555/livedemocam"

ffplay.exe -window_title "IP Camera" -vf "scale=1280:720" -rtsp_transport tcp "rtsp://104.194.11.25:555/livedemocam"

---

Applications

explorer shell:AppsFolder

---

Не удается включить сетевое обнаружение

@echo off

net start Dnscache & sc config Dnscache start=auto rem DNS-клиент
net start SSDPSRV & sc config SSDPSRV start=auto rem Обнаружение SSDP
net start FDResPub & sc config FDResPub start=auto rem Публикация ресурсов обнаружения функции
net start upnphost & sc config upnphost start=auto rem Узел универсальных PNP-устройств
net start fdPHost & sc config fdPHost start=auto rem Хост поставщика функции обнаружения

---

Параметры значков рабочего стола

@echo off

desk.cpl ,5
:: Rundll32 shell32.dll,Control_RunDLL desk.cpl,,5

---

Общий доступ(ресурс) к папке

:: Start

@echo off

set folder=files

if not exist %folder% mkdir %folder%

net share Share_folder=%~dp0%folder% /grant:User,full /users:5 /remark:"Share folder."

pause

rem ----------------------------------

:: Stop

@echo off

net share Share_folder /delete -y

---

Скачать файл по ссылке

@echo off

:: Вариант 1
curl --url https://smartfix.pro/SmartFix.exe --output SmartFix.exe

:: Вариант 2
set "download=bitsadmin /transfer myDownloadJob /download /priority FOREGROUND"
%download% "https://smartfix.pro/SmartFix.exe" %~dp0SmartFix.exe

:: Вариант 3
wget https://smartfix.pro/SmartFix.exe

:: Вариант 4
call :downloadFile "https://smartfix.pro/SmartFix.exe" "SmartFix.exe"

:downloadFile
curl -A "Mozilla/5.0 (compatible; MSIE 9.0; Windows NT 6.1; WOW64)" -L "%~1" -o "%~2"
goto :eof

---

Папка "Слежение за действиями пользователя"

@echo off
explorer recent

---

Проверки целостности системных файлов Windows

@echo off

sfc /scannow

explorer %windir%\logs\cbs\cbs.log

DISM /Online /Cleanup-Image /RestoreHealth

---

Открыть папку автозагрузка

@echo off

explorer "%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup"

pause

---

Переключаться между мониторами

@echo off

:: Win + P
displayswitch /clone

exit

---

Узнать статус, версия, ID AnyDesk

@echo off

rem https://tre.kz/

set anydesk_folder="%programfiles(x86)%\AnyDesk\AnyDesk.exe"

for /f "delims=" %%i in ('%anydesk_folder% --get-status') do set STATUS=%%i
for /f "delims=" %%i in ('%anydesk_folder% --version') do set VER=%%i
for /f "delims=" %%i in ('%anydesk_folder% --get-id') do set ID=%%i

echo ID: %ID%
echo Status: %STATUS%
echo Version: %VER%

pause

---

Сбросить идентификатор AnyDesk.

@echo off

rem Reset AnyDesk ID
rem https://tre.kz/

:: 1
call:kill_process_anydesk

:: 2
rmdir "%appdata%\AnyDesk\cache" /S /Q
rmdir "%appdata%\AnyDesk\global_cache" /S /Q
del "%appdata%\AnyDesk\ad.trace" /Q
del "%appdata%\AnyDesk\service.conf" /Q
del "%appdata%\AnyDesk\system.conf" /Q
copy %appdata%\AnyDesk\user.conf %COMPUTERNAME%.user.conf

:: 3
call:start_anydesk

:: 4
timeout 2
call:kill_process_anydesk

:: 5
call:start_anydesk

:: Functions

:kill_process_anydesk
tasklist /fi "imagename eq AnyDesk.exe" |find ":" > nul
if errorlevel 1 taskkill /f /im "AnyDesk.exe"
EXIT /B 0

:start_anydesk
start /min cmd /c "%programfiles(x86)%\AnyDesk\AnyDesk.exe"
EXIT /B 0

#!/bin/bash

# Это комментарий
echo Тут ваш код...